configure.in

   1 AC_INIT(daemon/main.c)
   2 AM_INIT_AUTOMAKE([doldaconnect], [1.1])
   3 AM_CONFIG_HEADER(config.h)
   4
   5 DOLDA_AC_GROUP([Checking build chain])
   6
   7 AC_PROG_CC
   8 AC_PROG_CC_C_O
   9 AM_PROG_CC_C_O
  10 AC_PROG_INSTALL
  11
  12 DOLDA_AC_GROUP([Configuring gettext])
  13
  14 AM_GNU_GETTEXT_VERSION(0.12.1)
  15 AM_GNU_GETTEXT([external])
  16
  17 DOLDA_AC_GROUP([Configuring libtool])
  18
  19 # Temporary hack to make libtool not check for g++ or g77
  20 m4_defun([_LT_AC_LANG_CXX_CONFIG], true)
  21 m4_defun([_LT_AC_LANG_F77_CONFIG], true)
  22 AC_PROG_LIBTOOL
  23
  24 experimental=no
  25
  26 DOLDA_AC_GROUP([Checking optional libraries])
  27
  28 # Standard libraries
  29 AC_CHECK_LIB(z, deflate, [HAS_LIBZ=yes], [HAS_LIBZ=no])
  30 AC_CHECK_LIB(bz2, BZ2_bzWriteOpen, [HAS_LIBBZ2=yes], [HAS_LIBBZ2=no])
  31 AC_CHECK_LIB(gdbm, gdbm_open, [HAS_GDBM=yes], [HAS_GDBM=no])
  32
  33 # PAM check
  34 pam_msg=no
  35 AH_TEMPLATE(HAVE_PAM, [define to compile support for PAM authentication])
  36 AC_ARG_WITH(pam, [  --with-pam              Enable PAM support])
  37 DOLDA_PKG([HAS_PAM], [test "$with_pam" = no && HAS_PAM=no],
  38                      [AC_CHECK_LIB(pam, pam_start, [:], [HAS_PAM=no])],
  39                      [PAM_LIBS=-lpam])
  40 if test "$with_pam" = yes -a "$HAS_PAM" = no; then
  41         AC_MSG_ERROR([*** cannot find PAM on this system])
  42 fi
  43 if test "$HAS_PAM" = yes; then
  44         AC_DEFINE(HAVE_PAM)
  45         pam_msg=yes
  46 fi
  47 AC_SUBST(PAM_LIBS)
  48
  49 # Gtk 2.0 check
  50 AC_ARG_WITH(gtk2, [  --with-gtk2             Enable GTK2 support])
  51 DOLDA_PKG([HAS_GTK2], [test "$with_gtk2" = no && HAS_GTK2=no],
  52                       [PKG_CHECK_MODULES(GTK2, gtk+-2.0, [], [HAS_GTK2=no])],
  53                       [AC_CHECK_LIB(gtk-x11-2.0, gtk_init, [:], [HAS_GTK2=no], $GTK2_LIBS)],
  54                       [DOLDA_CHECK_HEADER(gtk/gtk.h, [], [HAS_GTK2=no], $GTK2_CFLAGS)])
  55 if test "$with_gtk2" = yes -a "$HAS_GTK2" = no; then
  56         AC_MSG_ERROR([*** cannot find GTK2 on this system])
  57 fi
  58 DOLDA_PKG([HAS_GTK2SI], [test "$HAS_GTK2" = no && HAS_GTK2SI=no],
  59                         [DOLDA_CHECK_FUNC(gtk_status_icon_new_from_pixbuf, [], [HAS_GTK2SI=no], $GTK2_CFLAGS, $GTK2_LIBS)])
  60 DOLDA_PKG([HAS_GTK2ASS], [test "$HAS_GTK2" = no && HAS_GTK2ASS=no],
  61                          [DOLDA_CHECK_FUNC(gtk_assistant_new, [], [HAS_GTK2ASS=no], $GTK2_CFLAGS, $GTK2_LIBS)])
  62
  63 # libxml2 check
  64 AC_ARG_WITH(libxml2, [  --with-libxml2          Enable libxml2 support])
  65 DOLDA_PKG([HAS_LIBXML], [test "$with_libxml2" = no && HAS_LIBXML=no],
  66                         [PKG_CHECK_MODULES(LIBXML, libxml-2.0, [], [HAS_LIBXML=no])],
  67                         [AC_CHECK_LIB(xml2, xmlReadFile, [:], [HAS_LIBXML=no], $LIBXML_LIBS)],
  68                         [DOLDA_CHECK_HEADER(libxml/parser.h, [], [HAS_LIBXML=no], $LIBXML_CFLAGS)])
  69 if test "$with_libxml" = yes -a "$HAS_LIBXML" = no; then
  70         AC_MSG_ERROR([*** cannot find libxml2 on this system])
  71 fi
  72
  73 # libnotify check
  74 AH_TEMPLATE(HAVE_NOTIFY, [define to compile support for libnotify])
  75 AC_ARG_WITH(libnotify, [  --with-libnotify        Enable libnotify support])
  76 DOLDA_PKG([HAS_LIBNOTIFY], [test "$with_libnotify" = no && HAS_LIBNOTIFY=no],
  77                            [PKG_CHECK_MODULES(LIBNOTIFY, libnotify, [], [HAS_LIBNOTIFY=no])],
  78                            [AC_CHECK_LIB(notify, notify_init, [:], [HAS_LIBNOTIFY=no], $LIBNOTIFY_LIBS)])
  79 if test "$with_libnotify" = yes -a "$HAS_LIBNOTIFY" = no; then
  80         AC_MSG_ERROR([*** cannot find libnotify on this system])
  81 fi
  82 if test "$HAS_LIBNOTIFY" = yes; then
  83         AC_DEFINE(HAVE_NOTIFY)
  84 fi
  85
  86 # libpanelapplet check
  87 DOLDA_PKG([HAS_LIBPANELAPPLET], [PKG_CHECK_MODULES(PANELAPPLET, libpanelapplet-2.0, [], [HAS_LIBPANELAPPLET=no])])
  88
  89 # Gaim/Pidgin check
  90 DOLDA_PKG([HAS_LIBGAIM], [PKG_CHECK_MODULES(GAIM, gaim, [], [HAS_LIBGAIM=no])],
  91                          [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBGAIM=no], $GAIM_CFLAGS)])
  92 DOLDA_PKG([HAS_LIBPURPLE], [PKG_CHECK_MODULES(PURPLE, purple, [], [HAS_LIBPURPLE=no])],
  93                            [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBPURPLE=no], $PURPLE_CFLAGS)])
  94
  95 # Daemon check
  96 DOLDA_ENABLE(daemon, [  --enable-daemon         Enable the daemon], yes,
  97                      [HAS_LIBZ HAS_LIBBZ2 HAS_GDBM])
  98 AM_CONDITIONAL(DAEMON, test "$enable_daemon" = yes)
  99
 100 # Gtk GUI check
 101 DOLDA_ENABLE(gtk2ui, [  --enable-gtk2ui         Enable the GTK2 user interface], yes,
 102                      [HAS_GTK2 HAS_LIBBZ2 HAS_LIBXML])
 103 AM_CONDITIONAL(CLI_GTK2, test "$enable_gtk2ui" = yes)
 104
 105 # Dolconf check
 106 DOLDA_ENABLE(dolconf, [  --enable-dolconf        Build the configuration helper], yes,
 107                       [HAS_GTK2], [HAS_GTK2ASS])
 108 AM_CONDITIONAL(DOLCONF, test "$enable_dolconf" = yes)
 109
 110 # GUI shell check
 111 DOLDA_ENABLE(guishell, [  --enable-guishell       Build the GUI shell programs], yes,
 112                        [HAS_GTK2], [HAS_GTK2SI])
 113 AM_CONDITIONAL(GUISHELL, test "$enable_guishell" = yes)
 114
 115 # Gnome applet check
 116 DOLDA_ENABLE(gnomeapplet, [  --enable-gnomeapplet    Enable GNOME transfer applet (experimental)], no,
 117                           [HAS_LIBPANELAPPLET])
 118 if test "$enable_gnomeapplet" = yes; then
 119         experimental=yes
 120 fi
 121 AM_CONDITIONAL(CLI_GNOMEAPPLET, test "$enable_gnomeapplet" = yes)
 122
 123 # Gaim plugin check
 124 gaimplugin_msg=
 125 DOLDA_ENABLE(gaimplugin, [  --enable-gaimplugin     Enable Gaim chat plugin (experimental)], no,
 126                          [HAS_LIBGAIM])
 127 if test "$enable_gaimplugin" = yes; then
 128         experimental=yes
 129         gaimplugin_msg="Gaim $gaimplugin_msg"
 130 fi
 131 AM_CONDITIONAL(CLI_GAIM, test "$enable_gaimplugin" = yes)
 132 DOLDA_ENABLE(pidginplugin, [  --enable-pidginplugin   Enable Pidgin chat plugin (experimental)], no,
 133                            [HAS_LIBPURPLE])
 134 if test "$enable_pidginplugin" = yes; then
 135         experimental=yes
 136         gaimplugin_msg="Pidgin $gaimplugin_msg"
 137 fi
 138 AM_CONDITIONAL(CLI_PIDGIN, test "$enable_pidginplugin" = yes)
 139 if test -z "$gaimplugin_msg"; then
 140         gaimplugin_msg=none
 141 fi
 142
 143 # Guile check (XXX: Shouldn't have to be enabled manually)
 144 enable_guile=no
 145 if test "$with_guile" = yes; then
 146         GUILE_FLAGS
 147         enable_guile=yes
 148 fi
 149 AM_CONDITIONAL(ELIB_GUILE, test "$enable_guile" = yes)
 150
 151 # Check whether to install baseconv
 152 AC_ARG_ENABLE(baseconv, [  --enable-baseconv       Install the baseconv utility])
 153 AM_CONDITIONAL(BASECONV, test "$enable_baseconv" = yes)
 154
 155 # Kerberos check
 156 krb_msg=no
 157 AH_TEMPLATE(HAVE_KRB5, [define to compile support for Kerberos 5 (not GSSAPI) authentication])
 158 AC_ARG_WITH(krb5, [  --with-krb5[=PATH]        Enable Kerberos 5 (not GSSAPI) authentication])
 159 AC_CHECK_PROG(KRBCONF, krb5-config, yes, no)
 160 DOLDA_PKG([HAS_COMERR], [AC_CHECK_HEADER(com_err.h, [COMERR_CFLAGS=""; HAS_COMERR=yes], [])],
 161                         [AC_CHECK_HEADER(et/com_err.h, [COMERR_CFLAGS="-I/usr/include/et"; HAS_COMERR=yes], [])],
 162                         [HAS_COMERR=no])
 163 DOLDA_PKG([HAS_KRB5], [test "$with_krb5" = no && HAS_KRB5=no],
 164                       [test "$KRBCONF" != yes && HAS_KRB5=no],
 165                       [test "$HAS_COMERR" = no && HAS_KRB5=no],
 166                       [KRB5_LIBS="`krb5-config --libs krb5`"
 167                        KRB5_CFLAGS="`krb5-config --cflags krb5` $COMERR_CFLAGS"]
 168                       [AC_CHECK_LIB(krb5, krb5_init_context, [:], [HAS_KRB5=no], $KRB5_LIBS)],
 169                       [DOLDA_CHECK_HEADER(krb5.h, [], [HAS_KRB5=no], $KRB5_CFLAGS)])
 170 if test -n "$with_krb5" -a "$with_krb5" != no -a "$HAS_KRB5" = no; then
 171         AC_MSG_ERROR([*** cannot find Kerberos 5 on this system])
 172 fi
 173 if test "$with_krb5" != no -a "$HAS_KRB5" = yes; then
 174         AC_DEFINE(HAVE_KRB5)
 175         krb_msg=yes
 176 fi
 177 AC_SUBST([KRB5_LIBS KRB5_CFLAGS])
 178
 179 # Linux keyring
 180 AH_TEMPLATE(HAVE_KEYUTILS, [define if your system supports the Linux keyring functions])
 181 AC_ARG_WITH(keyutils, [  --with-keyutils           Enable support for the Linux keyring stash])
 182 DOLDA_PKG([HAS_KEYUTILS], [test "$with_keyutils" = no && HAS_KEYUTILS=no],
 183                           [AC_CHECK_LIB(keyutils, keyctl_search, [:], [HAS_KEYUTILS=no])])
 184 if test "$with_keyutils" = yes -a "$HAS_KEYUTILS" = no; then
 185         AC_MSG_ERROR([*** cannot find keyutils on this system])
 186 fi
 187 if test "$HAS_KEYUTILS" = yes; then
 188         AC_DEFINE(HAVE_KEYUTILS)
 189         KEYUTILS_LIBS=-lkeyutils
 190 fi
 191 AC_SUBST([KEYUTILS_LIBS])
 192
 193 DOLDA_AC_GROUP([Checking operating system features])
 194
 195 # Misc. functions checks
 196 AC_CHECK_FUNC(vswprintf, , AC_MSG_ERROR([*** must have vswprintf]))
 197 AH_TEMPLATE(HAVE_WCSCASECMP, [define if your system implements wcscasecmp])
 198 AC_CHECK_FUNC(wcscasecmp, [ AC_DEFINE(HAVE_WCSCASECMP) ])
 199
 200 AH_TEMPLATE(HAVE_LINUX_SOCKIOS_H, [define if you have linux/sockios.h on your system])
 201 AC_CHECK_HEADER([linux/sockios.h], [ AC_DEFINE(HAVE_LINUX_SOCKIOS_H) ])
 202
 203 AH_TEMPLATE(HAVE_IPV6, [define if your system supports IPv6 and you wish to compile with support for it])
 204 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_family, [ AC_DEFINE(HAVE_IPV6) ], , [#include <netinet/in.h>])
 205
 206 AH_TEMPLATE(HAVE_RESOLVER, [define if your system supports the res_* functions to fetch DNS RRs])
 207 AC_CHECK_LIB(resolv, res_query, [ AC_DEFINE(HAVE_RESOLVER)
 208                                   LDFLAGS="$LDFLAGS -lresolv" ])
 209 AC_CHECK_LIB(resolv, __res_query, [ AC_DEFINE(HAVE_RESOLVER)
 210                                     LDFLAGS="$LDFLAGS -lresolv" ])
 211
 212 # Unix credentials selector
 213 AH_TEMPLATE(UNIX_AUTH_STYLE, [undefine for no Unix auth, 1 for Linux style, 2 for BSD style])
 214 AC_CHECK_MEMBER(struct ucred.pid, [ linuxcreds=y ], [ linuxcreds=n ], [#include <sys/socket.h>])
 215 AC_CHECK_FUNC(getpeereid, [ bsdcreds=y ], [ bsdcreds=n ])
 216 AC_MSG_CHECKING([for Unix auth style])
 217 if test $linuxcreds = y; then
 218         AC_DEFINE(UNIX_AUTH_STYLE, 1)
 219         AC_MSG_RESULT(linux)
 220 elif test $bsdcreds = y; then
 221         AC_DEFINE(UNIX_AUTH_STYLE, 2)
 222         AC_MSG_RESULT(bsd)
 223 else
 224         AC_MSG_RESULT(none)
 225 fi
 226
 227 DOLDA_AC_GROUP([Checking standard headers])
 228
 229 AC_HEADER_STDC
 230 AC_HEADER_DIRENT
 231 AC_HEADER_SYS_WAIT
 232
 233 AC_TYPE_PID_T
 234 AC_TYPE_SIZE_T
 235 AC_HEADER_TIME
 236 AC_TYPE_SIGNAL
 237
 238 CPPFLAGS="-I\$(top_srcdir)/include $CPPFLAGS"
 239
 240 DOLDA_AC_GROUP([Writing output])
 241
 242 AH_TEMPLATE(RELEASEINFO, [define release information reported by various programs (should be left to configure to define)])
 243 relinfo="relver ${VERSION}\\n"
 244 relinfo="${relinfo}builddate $(date)\\n"
 245 if test -d .git && which git-rev-parse >/dev/null 2>&1; then
 246         relinfo="${relinfo}source git $(git-rev-parse HEAD)\\n"
 247 elif test -r source; then
 248         relinfo="${relinfo}source $(cat source)\\n"
 249 else
 250         relinfo="${relinfo}source unknown\\n"
 251 fi
 252 AC_DEFINE_UNQUOTED([RELEASEINFO], ["$relinfo"])
 253
 254 AC_OUTPUT([
 255 Makefile
 256 autopackage/Makefile
 257 common/Makefile
 258 daemon/Makefile
 259 lib/Makefile
 260 lib/guile/Makefile
 261 lib/guile/dolcon/Makefile
 262 clients/Makefile
 263 clients/gtk2/Makefile
 264 clients/tty/Makefile
 265 clients/gnome-trans-applet/Makefile
 266 clients/gaim/Makefile
 267 clients/gui-shell/Makefile
 268 include/Makefile
 269 include/doldaconnect/Makefile
 270 doc/Makefile
 271 doc/man/Makefile
 272 po/Makefile.in
 273 config/Makefile
 274 config/cmd/Makefile
 275 config/util/Makefile
 276 contrib/Makefile
 277 contrib/doldaconnect.spec
 278 share/Makefile
 279 autopackage/doldacond.apspec
 280 autopackage/dolcon.apspec
 281 autopackage/dcuilib.apspec
 282 autopackage/dcguile.apspec
 283 autopackage/guishell.apspec
 284 ])
 285
 286 echo
 287 echo "Dolda Connect has been configured with the following settings:"
 288 echo
 289 echo "    Daemon:                  $enable_daemon"
 290 echo "    PAM support:             $pam_msg"
 291 echo "    Kerberos 5 support:      $krb_msg"
 292 echo "    GTK2 user interface:     $enable_gtk2ui"
 293 echo "    Dolconf configurator:    $enable_dolconf"
 294 echo "    GUI shell:               $enable_guishell"
 295 echo "    Guile extension library: $enable_guile"
 296 echo "    GNOME transfer applet:   $enable_gnomeapplet"
 297 echo "    Gaim chat plugin:        $gaimplugin_msg"
 298 echo
 299
 300 if tput bold >/dev/null 2>&1 && tty <&2 >/dev/null 2>&1; then
 301         hastput=y
 302 fi
 303 if test "$HAS_GTK2" = no -a "$with_gtk2" != no -a "$enable_gtk2ui" != no; then
 304         if test "$hastput" = y; then
 305                 tput bold
 306                 tput setf 4 2>/dev/null
 307         fi
 308         echo -n "    Warning: " >&2
 309         if test "$hastput" = y; then
 310                 tput sgr0
 311         fi
 312         echo "Could not find a GTK2 development installation on this system." >&2
 313         echo "             That means you won't get a UI." >&2
 314         echo "             Make absolutely sure this is what you want!" >&2
 315         if test "$hastput" = y; then
 316                 tput bel
 317         fi
 318         sleep 1
 319 fi
 320 if test "$experimental" = yes; then
 321         if test "$hastput" = y; then
 322                 tput bold
 323                 tput setf 4 2>/dev/null
 324         fi
 325         echo -n "    Warning: " >&2
 326         if test "$hastput" = y; then
 327                 tput sgr0
 328         fi
 329         echo "You have enabled one or more experimental features!" >&2
 330         echo "             Please don't complain that it doesn't work, unless" >&2
 331         echo "             you have something constructive to add about the situation." >&2
 332         if test "$hastput" = y; then
 333                 tput bel
 334         fi
 335         sleep 1
 336 fi